mirror of
https://github.com/qgis/QGIS.git
synced 2025-02-25 00:58:06 -05:00
251 lines
8.7 KiB
Batchfile
251 lines
8.7 KiB
Batchfile
@echo off
|
|
REM ***************************************************************************
|
|
REM package-nightly.cmd
|
|
REM ---------------------
|
|
REM begin : January 2011
|
|
REM copyright : (C) 2011 by Juergen E. Fischer
|
|
REM email : jef at norbit dot de
|
|
REM ***************************************************************************
|
|
REM * *
|
|
REM * This program is free software; you can redistribute it and/or modify *
|
|
REM * it under the terms of the GNU General Public License as published by *
|
|
REM * the Free Software Foundation; either version 2 of the License, or *
|
|
REM * (at your option) any later version. *
|
|
REM * *
|
|
REM ***************************************************************************
|
|
set GRASS_VERSION=6.4.3
|
|
|
|
set VERSION=%1
|
|
set PACKAGE=%2
|
|
set PACKAGENAME=%3
|
|
set ARCH=%4
|
|
if "%VERSION%"=="" goto usage
|
|
if "%PACKAGE%"=="" goto usage
|
|
if "%PACKAGENAME%"=="" goto usage
|
|
if "%ARCH%"=="" goto usage
|
|
|
|
set BUILDDIR=%CD%\build-nightly-%ARCH%
|
|
|
|
if "%OSGEO4W_ROOT%"=="" (
|
|
if "%ARCH%"=="x86" (
|
|
set OSGEO4W_ROOT=C:\OSGeo4W
|
|
) else (
|
|
set OSGEO4W_ROOT=C:\OSGeo4W64
|
|
)
|
|
)
|
|
|
|
if not exist "%BUILDDIR%" mkdir %BUILDDIR%
|
|
if not exist "%BUILDDIR%" (echo could not create build directory %BUILDDIR% & goto error)
|
|
|
|
if not exist "%OSGEO4W_ROOT%\bin\o4w_env.bat" (echo o4w_env.bat not found & goto error)
|
|
call "%OSGEO4W_ROOT%\bin\o4w_env.bat"
|
|
|
|
set O4W_ROOT=%OSGEO4W_ROOT:\=/%
|
|
set LIB_DIR=%O4W_ROOT%
|
|
|
|
if not "%PROGRAMFILES(X86)%"=="" set PF86=%PROGRAMFILES(X86)%
|
|
if "%PF86%"=="" set PF86=%PROGRAMFILES%
|
|
if "%PF86%"=="" (echo PROGRAMFILES not set & goto error)
|
|
|
|
if "%ARCH%"=="x86" goto devenv_x86
|
|
goto devenv_x86_64
|
|
|
|
:devenv_x86
|
|
set VS90COMNTOOLS=%PF86%\Microsoft Visual Studio 9.0\Common7\Tools\
|
|
call "%PF86%\Microsoft Visual Studio 9.0\VC\vcvarsall.bat" x86
|
|
|
|
set CMAKE_OPT=^
|
|
-G "Visual Studio 9 2008" ^
|
|
-D BUILDNAME="OSGeo4W-Nightly-VC9" ^
|
|
-D SIP_BINARY_PATH=%O4W_ROOT%/apps/Python27/sip.exe ^
|
|
-D CMAKE_CXX_FLAGS_RELWITHDEBINFO="/MD /ZI /MP /Od /D NDEBUG /D QGISDEBUG"
|
|
goto devenv
|
|
|
|
:devenv_x86_64
|
|
call "%PF86%\Microsoft Visual Studio 10.0\VC\vcvarsall.bat" amd64
|
|
if exist "c:\Program Files\Microsoft SDKs\Windows\v7.1\Bin\SetEnv.Cmd" call "c:\Program Files\Microsoft SDKs\Windows\v7.1\Bin\SetEnv.Cmd" /x64 /Release
|
|
path %path%;%PF86%\Microsoft Visual Studio 10.0\VC\bin
|
|
|
|
set SETUPAPI_LIBRARY=%PF86%\Microsoft SDKs\Windows\v7.0A\Lib\x64\SetupAPI.Lib
|
|
if not exist "%SETUPAPI_LIBRARY%" set SETUPAPI_LIBRARY=%PROGRAMFILES%\Microsoft SDKs\Windows\v7.1\Lib\x64\SetupAPI.lib
|
|
if not exist "%SETUPAPI_LIBRARY%" (echo SETUPAPI_LIBRARY not found & goto error)
|
|
|
|
set CMAKE_OPT=^
|
|
-G "Visual Studio 10 Win64" ^
|
|
-D BUILDNAME="OSGeo4W-Nightly-VC10-64" ^
|
|
-D SPATIALINDEX_LIBRARY=%O4W_ROOT%/lib/spatialindex-64.lib ^
|
|
-D SIP_BINARY_PATH=%O4W_ROOT%/bin/sip.exe ^
|
|
-D CMAKE_CXX_FLAGS_RELWITHDEBINFO="/MD /Zi /MP /Od /D NDEBUG /D QGISDEBUG" ^
|
|
-D SETUPAPI_LIBRARY="%SETUPAPI_LIBRARY%" ^
|
|
-D CMAKE_INSTALL_SYSTEM_RUNTIME_LIBS_NO_WARNINGS=TRUE
|
|
|
|
:devenv
|
|
set PYTHONPATH=
|
|
path %PF86%\CMake 2.8\bin;%PATH%;c:\cygwin\bin
|
|
|
|
PROMPT qgis%VERSION%$g
|
|
|
|
set BUILDCONF=RelWithDebInfo
|
|
|
|
cd ..\..
|
|
set SRCDIR=%CD%
|
|
|
|
if "%BUILDDIR:~1,1%"==":" %BUILDDIR:~0,2%
|
|
cd %BUILDDIR%
|
|
|
|
if exist repackage goto package
|
|
|
|
if not exist build.log goto build
|
|
|
|
REM
|
|
REM try renaming the logfile to see if it's locked
|
|
REM
|
|
|
|
if exist build.tmp del build.tmp
|
|
if exist build.tmp (echo could not remove build.tmp & goto error)
|
|
|
|
ren build.log build.tmp
|
|
if exist build.log goto locked
|
|
if not exist build.tmp goto locked
|
|
|
|
ren build.tmp build.log
|
|
if exist build.tmp goto locked
|
|
if not exist build.log goto locked
|
|
|
|
goto build
|
|
|
|
:locked
|
|
echo Logfile locked
|
|
if exist build.tmp del build.tmp
|
|
goto error
|
|
|
|
:build
|
|
echo BEGIN: %DATE% %TIME%
|
|
|
|
set >buildenv.log
|
|
|
|
if exist qgsversion.h del qgsversion.h
|
|
|
|
if exist CMakeCache.txt goto skipcmake
|
|
|
|
echo CMAKE: %DATE% %TIME%
|
|
if errorlevel 1 goto error
|
|
|
|
set LIB=%LIB%;%OSGEO4W_ROOT%\lib
|
|
set INCLUDE=%INCLUDE%;%OSGEO4W_ROOT%\include
|
|
set GRASS_PREFIX=%O4W_ROOT%/apps/grass/grass-%GRASS_VERSION%
|
|
|
|
cmake %CMAKE_OPT% ^
|
|
-D SITE="qgis.org" ^
|
|
-D PEDANTIC=TRUE ^
|
|
-D WITH_QSPATIALITE=TRUE ^
|
|
-D WITH_MAPSERVER=TRUE ^
|
|
-D MAPSERVER_SKIP_ECW=TRUE ^
|
|
-D WITH_ASTYLE=TRUE ^
|
|
-D WITH_GLOBE=TRUE ^
|
|
-D WITH_TOUCH=TRUE ^
|
|
-D WITH_ORACLE=TRUE ^
|
|
-D WITH_GRASS=TRUE ^
|
|
-D CMAKE_BUILD_TYPE=%BUILDCONF% ^
|
|
-D CMAKE_CONFIGURATION_TYPES=%BUILDCONF% ^
|
|
-D GEOS_LIBRARY=%O4W_ROOT%/lib/geos_c.lib ^
|
|
-D SQLITE3_LIBRARY=%O4W_ROOT%/lib/sqlite3_i.lib ^
|
|
-D SPATIALITE_LIBRARY=%O4W_ROOT%/lib/spatialite_i.lib ^
|
|
-D PYTHON_EXECUTABLE=%O4W_ROOT%/bin/python.exe ^
|
|
-D PYTHON_INCLUDE_PATH=%O4W_ROOT%/apps/Python27/include ^
|
|
-D PYTHON_LIBRARY=%O4W_ROOT%/apps/Python27/libs/python27.lib ^
|
|
-D QT_BINARY_DIR=%O4W_ROOT%/bin ^
|
|
-D QT_LIBRARY_DIR=%O4W_ROOT%/lib ^
|
|
-D QT_HEADERS_DIR=%O4W_ROOT%/include/qt4 ^
|
|
-D QWT_INCLUDE_DIR=%O4W_ROOT%/include/qwt ^
|
|
-D QWT_LIBRARY=%O4W_ROOT%/lib/qwt5.lib ^
|
|
-D CMAKE_INSTALL_PREFIX=%O4W_ROOT%/apps/%PACKAGENAME% ^
|
|
-D FCGI_INCLUDE_DIR=%O4W_ROOT%/include ^
|
|
-D FCGI_LIBRARY=%O4W_ROOT%/lib/libfcgi.lib ^
|
|
-D WITH_INTERNAL_JINJA2=FALSE ^
|
|
-D WITH_INTERNAL_MARKUPSAFE=FALSE ^
|
|
-D WITH_INTERNAL_PYGMENTS=FALSE ^
|
|
-D WITH_INTERNAL_DATEUTIL=FALSE ^
|
|
-D WITH_INTERNAL_PYTZ=FALSE ^
|
|
-D WITH_INTERNAL_SIX=FALSE ^
|
|
%SRCDIR%
|
|
if errorlevel 1 (echo cmake failed & goto error)
|
|
|
|
:skipcmake
|
|
if exist noclean (echo skip clean & goto skipclean)
|
|
echo CLEAN: %DATE% %TIME%
|
|
cmake --build %BUILDDIR% --target clean --config %BUILDCONF%
|
|
if errorlevel 1 (echo clean failed & goto error)
|
|
|
|
:skipclean
|
|
echo ALL_BUILD: %DATE% %TIME%
|
|
cmake --build %BUILDDIR% --config %BUILDCONF%
|
|
if errorlevel 1 cmake --build %BUILDDIR% --config %BUILDCONF%
|
|
if errorlevel 1 (echo build failed twice & goto error)
|
|
|
|
if not exist ..\skiptests (
|
|
echo RUN_TESTS: %DATE% %TIME%
|
|
cmake --build %BUILDDIR% --target Nightly --config %BUILDCONF%
|
|
if errorlevel 1 echo TESTS WERE NOT SUCCESSFUL.
|
|
)
|
|
|
|
set PKGDIR=%OSGEO4W_ROOT%\apps\%PACKAGENAME%
|
|
|
|
if exist %PKGDIR% (
|
|
echo REMOVE: %DATE% %TIME%
|
|
rmdir /s /q %PKGDIR%
|
|
)
|
|
|
|
echo INSTALL: %DATE% %TIME%
|
|
cmake --build %BUILDDIR% --target INSTALL --config %BUILDCONF%
|
|
if errorlevel 1 (echo INSTALL failed & goto error)
|
|
|
|
:package
|
|
echo PACKAGE: %DATE% %TIME%
|
|
|
|
cd ..
|
|
sed -e 's/@package@/%PACKAGENAME%/g' -e 's/@version@/%VERSION%/g' -e 's/@grassversion@/%GRASS_VERSION%/g' postinstall-dev.bat >%OSGEO4W_ROOT%\etc\postinstall\%PACKAGENAME%.bat
|
|
sed -e 's/@package@/%PACKAGENAME%/g' -e 's/@version@/%VERSION%/g' -e 's/@grassversion@/%GRASS_VERSION%/g' preremove-desktop.bat >%OSGEO4W_ROOT%\etc\preremove\%PACKAGENAME%.bat
|
|
sed -e 's/@package@/%PACKAGENAME%/g' -e 's/@version@/%VERSION%/g' -e 's/@grassversion@/%GRASS_VERSION%/g' qgis.bat.tmpl >%OSGEO4W_ROOT%\bin\%PACKAGENAME%.bat.tmpl
|
|
sed -e 's/@package@/%PACKAGENAME%/g' -e 's/@version@/%VERSION%/g' -e 's/@grassversion@/%GRASS_VERSION%/g' browser.bat.tmpl >%OSGEO4W_ROOT%\bin\%PACKAGENAME%-browser.bat.tmpl
|
|
sed -e 's/@package@/%PACKAGENAME%/g' -e 's/@version@/%VERSION%/g' -e 's/@grassversion@/%GRASS_VERSION%/g' qgis.reg.tmpl >%OSGEO4W_ROOT%\apps\%PACKAGENAME%\bin\qgis.reg.tmpl
|
|
|
|
REM sed -e 's/%OSGEO4W_ROOT:\=\\\\\\\\%/@osgeo4w@/' %OSGEO4W_ROOT%\apps\%PACKAGENAME%\python\qgis\qgisconfig.py >%OSGEO4W_ROOT%\apps\%PACKAGENAME%\python\qgis\qgisconfig.py.tmpl
|
|
REM if errorlevel 1 (echo creation of qgisconfig.py.tmpl failed & goto error)
|
|
|
|
REM del %PKGDIR%\python\qgis\qgisconfig.py
|
|
|
|
touch exclude
|
|
|
|
move %PKGDIR%\bin\qgis.exe %OSGEO4W_ROOT%\bin\%PACKAGENAME%-bin.exe
|
|
move %PKGDIR%\bin\qbrowser.exe %OSGEO4W_ROOT%\bin\%PACKAGENAME%-browser-bin.exe
|
|
|
|
if not exist %ARCH%\release\qgis\%PACKAGENAME% mkdir %ARCH%\release\qgis\%PACKAGENAME%
|
|
tar -C %OSGEO4W_ROOT% -cjf %ARCH%/release/qgis/%PACKAGENAME%/%PACKAGENAME%-%VERSION%-%PACKAGE%.tar.bz2 ^
|
|
--exclude-from exclude ^
|
|
apps/%PACKAGENAME% ^
|
|
bin/%PACKAGENAME%-bin.exe ^
|
|
bin/%PACKAGENAME%-browser-bin.exe ^
|
|
bin/%PACKAGENAME%.bat.tmpl ^
|
|
bin/%PACKAGENAME%-browser.bat.tmpl ^
|
|
apps/qt4/plugins/sqldrivers/qsqlocispatial.dll ^
|
|
apps/qt4/plugins/sqldrivers/qsqlspatialite.dll ^
|
|
etc/postinstall/%PACKAGENAME%.bat ^
|
|
etc/preremove/%PACKAGENAME%.bat
|
|
if errorlevel 1 (echo tar failed & goto error)
|
|
|
|
goto end
|
|
|
|
:usage
|
|
echo usage: %0 version package packagename arch
|
|
echo sample: %0 2.1.0 38 qgis-dev x86_64
|
|
exit
|
|
|
|
:error
|
|
echo BUILD ERROR %ERRORLEVEL%: %DATE% %TIME%
|
|
echo BUILD ERROR %ERRORLEVEL%: %DATE% %TIME%
|
|
if exist %PACKAGENAME%-%VERSION%-%PACKAGE%.tar.bz2 del %PACKAGENAME%-%VERSION%-%PACKAGE%.tar.bz2
|
|
|
|
:end
|
|
echo FINISHED: %DATE% %TIME%
|